Personal Computer World 2009 February/PCWFEB09.iso/Software/Shareware/IDimager Personal 4.2.0.3/setup_IDimager_Personal_V4.exe/{app}/Scripts/Version Scripts/Remove versions from a version set that are in a specific placeholders.psc

Text File | 2008-09-29 | 4KB | 126 lines

{
Author: HB van Zwietering
First version: 2008-09-29

this script will remove images from a version set that are placed in a specific
place holder (if existing).
}
var
  ADlg: TForm;
  APlaceHolders: TCatalogPlaceHolders;
  AListView: TListView;

  procedure CreateDialog;
  var
    ALbl: TLabel;
    AOk: TButton;
    ACol: TListColumn;
    ALItem: TListItem;
    i: Integer;
  begin
    ADlg := TForm.Create (Screen.ActiveForm);
    ADlg.Caption := 'Select place holders to remove the versions from...';
    ADlg.Height  := 400;
    ADlg.Width   := 400;
    ADlg.Position := poScreenCenter;

    AOk := TButton.Create (ADlg);
    AOk.Parent := ADlg;
    AOk.Top := ADlg.ClientHeight - 10 - AOk.Height;
    AOk.Caption := '&Ok';
    AOk.Default := True;
    AOk.Left := 5;
    AOk.ModalResult := mrOk;

    AListView := TListView.Create (ADlg);
    AListView.Parent := ADlg;
    AListView.Anchors := [akLeft, akTop, akRight];
    AListView.Top := 15;
    AListView.Left := 5;
    AListView.Width := ADlg.ClientWidth - (2*5);
    AListView.Height := AOk.Top - 5 - AListView.Top;
    AListView.ViewStyle := vsReport;
    AListView.ReadOnly := True;
    AListView.RowSelect := True;
    AListView.CheckBoxes := True;

    ACol := AListView.Columns.Add;
    ACol.Caption := 'Placeholders';
    ACol.Width := AListView.ClientWidth - 20;      // leave some room for the scrollbar

    for i := 0 to APlaceHolders.Count - 1 do
    begin
      if APlaceHolders.Items[i].Visible then
      begin
        ALItem := AListView.Items.Add;
        ALItem.Caption := APlaceHolders.Items[i].PlaceHolder;
      end;
    end;
  end;

  procedure ProcessImage (AImage: TImageItem; APhs: TCatalogPlaceHolders);
  var
    AMain: TCatalogItem;
    ACatItem: TCatalogItem;
    i: Integer;
  begin
    AMain := TCatalogItem.Create(nil);
    try
      if not Catalog.FindImageCombined (AImage, AMain, True, vptNone) then
        exit;

      for i := 0 to APhs.Count - 1 do
      begin
        ACatItem := TCatalogItem.Create(nil);
        if Catalog.EnumVersionForPlaceHolderInMain (AMain, APhs.Items[i], ACatItem) then
          Catalog.DeleteVersionItem (ACatItem);
        ACatItem.Free;
      end;
    finally
      AMain.Free;
    end;
  end;

var
  i: Integer;
  ASelectedPlaceHolders: TCatalogPlaceHolders;
begin
  APlaceHolders := TCatalogPlaceHolders.Create (TCatalogPlaceHolder, '');
  ASelectedPlaceHolders := TCatalogPlaceHolders.Create (TCatalogPlaceHolder, '');

  Catalog.EnumPlaceHolders (APlaceHolders, False);    // read all placeholders, without image counts

  // create a dialog
  CreateDialog;
  ADlg.ShowModal;

  if ADlg.ModalResult = mrOk then
  begin
    // find all selected place holders
    for i := 0 to AListView.Items.Count - 1 do
    begin
      if AListView.Items.Item[i].Checked then
      begin
        //Say (APlaceHolders.Items[i].PlaceHolder);
        APlaceHolders.Items[i].CopyTo (ASelectedPlaceHolders, False);
      end;
    end;

    if ASelectedPlaceHolders.Count > 0 then
    begin
      if Ask (WideFormat('Are you sure you want to remove the images assigned to the selected placeholder%s from their version set?', [iif(ASelectedPlaceHolders.Count > 1, 's', '')])) then
      begin
        for i := 0 to Selected.Count - 1 do
          ProcessImage (Selected.Items[i], ASelectedPlaceHolders);
      end;
    end;
  end;

  ADlg.Free;
  ASelectedPlaceHolders.Free;
  APlaceHolders.Free;

  RefreshPanels;
  InvalidateCollection;
end;